ClockSync

Mantieni sincronizzato il tuo orologio di Windows.

ClockSync è un semplice script da riga di comando per mantenere sincronizzato l'orologio di Windows.
In alcuni sistemi e per diverse cause, l'orologio di Windows può spesso non essere sincronizzato.
Questo piccolo strumento dovrebbe risolvere questo problema.
ClockSync è scritto in linguaggio batch.

Se stai cercando un programma per mantenere l'ora esatta del tuo sistema, l'hai appena trovato!

  • Gratis
  • Open Source
  • Piccolo: meno di 2 kb
  • Veloce e facile da usare
  • Funziona su qualsiasi Windows da Win7 fino a Win10, incluse le edizioni Server.
    Sono supportati sia i sistemi operativi a 32 bit che quelli a 64 bit.
Uso:
  1. Assicurati di essere connesso a Internet.
  2. Esegui il file ClockSync.bat con privilegi di amministratore.

ClockSync eseguirà automaticamente una prima sincronizzazione.
Successivamente, esegue sincronizzazioni periodiche su un intervallo di tempo.
Per impostazione predefinita, sincronizza l'ora ogni 10 minuti.

Se vuoi specificare a intervallo di risincronizzazione personalizzato, eseguire il file con un parametro di comando "minuti".
Il comando seguente, ad esempio, sincronizza l'orologio ogni 60 minuti:
"ClockSync.bat 60"

Caratteristiche:

ClockSync manterrà l'orologio di sistema accurato eseguendo sincronizzazioni periodiche con l'Internet Time Server predefinito.

Se il servizio ora di Windows o la sincronizzazione dell'ora Internet sono stati disabilitati, ClockSync li riavvierà.
Ciò contribuirà a mantenere l'orologio di sistema accurato anche quando ClockSync non è in esecuzione.

Codice sorgente:

ClockSync.bat :

@echo off
echo * ClockSync v1.0
echo * BreakingSecurity.net
echo.
:: Check that we own administrator access level. 
echo [INFO] Checking Access Level...
net session >nul 2>&1
if %errorLevel% == 0 (
	:: We have the necessary rights, go forward
	echo [INFO] Administrative Access confirmed.
) else (
	:: Error, insufficient privileges. Exit program.
	echo [ERROR] Insufficient Access Level. Please restart script with administrative permission.
	echo.
	echo Press any key to exit...
	pause > nul
	exit
)
:: Check command-line parameter.
:: User can specify any number of minutes for the Resync interval.
:: If there is no user-specified parameter, default one is used.
set /A minutes = 10
if not "%1" == "" (
	set /A minutes=%1
)
:loop
:: Synchronize Clock
:: Use /force parameter to bypass "time change too big" error
w32tm /resync /force
if not errorlevel 0 (
	:: If Error, restart time service
    echo [WARNING] Time Service error. Restarting service...
	net stop w32time
    w32tm /unregister
    w32tm /register
    net start w32time
	w32tm /resync /force
	if not errorlevel 0 (
		:: Unknown error, exit program.
		echo [ERROR] Unknown error.
		echo.
		echo Press any key to exit...
		pause > nul
		exit
	)
)
echo.
echo [SUCCESS] Clock successfully synchronized!
echo Date: %date%
echo Time: %time%
echo.
:: Sleep
set /A seconds = %minutes% * 60
echo [INFO] Sleeping for %minutes% minutes until next synchronization...
echo.
ping 127.0.0.1 -n %seconds% > nul
:: Repeat
goto loop
Menu